Cómo usar la función FECHA de Excel

Qué saber

• La sintaxis de la función FECHA es =FECHA(año,mes,día). Por ejemplo: =FECHA(1986,3,18)
• Puede extraer el año, el mes y el día de otras celdas. Por ejemplo: =FECHA(A2,B2,C2)
• Resta meses y días usando argumentos negativos. Por ejemplo: =FECHA(2020,-2, -15)

Este artículo explica cómo usar la función FECHA de Excel en cada versión de Excel.

Sintaxis y argumentos de la función DATE

La función FECHA de Excel combina tres valores para crear una fecha. Cuando especifica el año, el mes y el día, Excel produce un número de serie que luego se puede formatear como una fecha de apariencia normal.

La forma típica de ingresar una fecha en Excel es escribir la fecha completa dentro de una celda, pero eso es un inconveniente cuando se trata de mucha información. La función FECHA puede ser útil si la fecha no tiene el formato correcto, como si se combina con texto normal o se distribuye en varias celdas.

Así es como se debe escribir cada instancia de la función de fecha para que Excel la procese correctamente:

= FECHA (año, mes, día)

• Año: Ingrese el año como un número de uno a cuatro dígitos de longitud o ingrese la referencia de celda a la ubicación de los datos en la hoja de trabajo. El argumento del año es obligatorio.
• Mes: Ingrese el mes del año como un número entero positivo o negativo del 1 al 12 (enero a diciembre) o ingrese la celda de referencia a la ubicación de los datos. El argumento del mes es obligatorio.
• Día: Ingrese el día del mes como un número entero positivo o negativo del 1 al 31 o ingrese la celda de referencia a la ubicación de los datos. Se requiere el argumento del día.

Información adicional sobre la función de fecha

Aquí hay algunas otras cosas importantes que debe saber sobre los argumentos de año, mes y día:

AÑO

• De forma predeterminada, Excel usa el sistema de fechas de 1900, lo que significa que la función FECHA no mostrará el año correctamente para nada anterior a 1900.
• Ingresar 0 como el valor del año es lo mismo que ingresar 1900, 1 es igual a 1901, 105 es 2005, etc.

MES

• Exceder 12 como valor del mes agregará ese número de meses al valor del año. 13, entonces, agrega un año y un mes a la fecha.
• Usar un número negativo como valor del mes restará ese número de meses, más uno, del primer mes del año.

DÍA

• Si el valor del día excede la cantidad de días que tiene ese mes, los días en exceso se agregan al primer día del mes siguiente.
• Un valor de día negativo resta ese número de días, más uno, del primer día del mes.

Ejemplos de la función FECHA

A continuación hay una serie de fórmulas del mundo real que usan la función FECHA:

Año, mes y día en otras celdas


=DATE(A2,B2,C2)


Este ejemplo de la función FECHA usa A2 para el año, B2 para el mes y C2 para el día.

Año en fórmula y mes y día en otra celda


=DATE(2020,A2,B2)


También puede mezclar cómo se obtienen los datos. En este ejemplo, estamos haciendo que 2020 sea el argumento del año, pero el mes y el día se extraen de otras celdas.

Restar meses usando el argumento de mes negativo


=DATE(2020,-2,15)


Aquí, estamos usando un número negativo en el espacio del mes. Esto se mueve hacia atrás a lo largo del año en lugar de hacia adelante, comenzando en enero de 2020 (ya que la fórmula incluye 2020). Esta fórmula DATE produce el 15/10/2019.

Restar días usando el argumento de día negativo


=DATE(2020,1,-5)


Sin el número negativo, esta fecha se calcularía como 5/1/2020. Sin embargo, el valor del día negativo es restar cinco días (más uno) del 1/1/2020, lo que produce la fecha 26/12/2019.

Grandes argumentos de día y mes


=DATE(2020,19,50)


Este ejemplo combina algunas de las reglas mencionadas anteriormente. El valor del año aumentará a partir de 2020 porque el mes supera los 12, y el mes que se calculará también cambiará, ya que el valor del día supera la cantidad de días de cualquier mes. Esta fórmula DATE produce el 19/8/2021.

Agregar 10 años hasta la fecha en otra celda


=DATE(YEAR(A2)+10,MONTH(A2),DAY(A2))


La función FECHA de Excel también se puede usar con otras fechas, como para agregar tiempo a una fecha existente. En este ejemplo, queremos ver la fecha que es 10 años después de una fecha existente. La fecha existente está en la celda E2, por lo que debemos escribir esta fórmula de manera que extraiga el año, el mes y el día de E2 pero que también agregue 10 al valor del año.

Calcular el número de días en el año


=A2-DATE(YEAR(A2),1,0)


Aquí hay un ejemplo similar de la función FECHA donde estamos calculando cuántos días en el año es la fecha en la celda E10. Por ejemplo, el 1/1/2020 es un día en el año, el 5 de enero es cinco días, y así sucesivamente. En este ejemplo, E10 es 4/8/2018, por lo que el resultado es 216.

Convertir fecha como texto a fecha con el formato correcto


=DATE(LEFT(A2,4),MID(A2,5,2),RIGHT(A2,2))


Si la celda con la que está tratando contiene la fecha completa pero tiene el formato de texto, como 20200417, puede usar esta fórmula de FECHA, combinada con las funciones IZQUIERDA, MEDIA y DERECHA, para convertir la celda a una fecha con el formato adecuado.

Lo que está haciendo es extraer los primeros cuatro dígitos de la izquierda con IZQUIERDA (A2,4), tomando dos dígitos del medio en el quinto carácter a través de MID (A2,5,2) y combinándolos con los dos últimos dígitos de la derecha con RIGHT(A2,2). La fecha calculada es el 17/04/2020.

Consulte nuestros artículos sobre el uso de las funciones IZQUIERDA, DERECHA y MID de Excel para obtener más información.

Este año y mes en un día específico


=DATE(YEAR(TODAY()), MONTH(TODAY()), 5)


La función HOY se puede usar con la función FECHA para obtener información sobre el día de hoy. Por ejemplo, para recordar pagar las facturas todos los meses el día 5, puede usar esta fórmula FECHA para agregar automáticamente el año y el mes actuales, pero luego colocar 5 (o una referencia de celda) como el valor del día.

Calcular fecha cuando el mes es texto


=DATE(A2,MONTH(1&B2),C2)


A veces, una fecha incluye la versión de texto del mes, como junio. Como Excel no entiende esto como un número, debe convertirlo a uno con la función MES. Hemos incrustado esto directamente en la fórmula FECHA, en la posición del mes, como MES(1&B2).

Fijar fechas que no parecen fechas

Si el resultado de la función FECHA muestra un montón de números en lugar de una fecha, deberá formatear la celda como una fecha.

Por ejemplo, es posible que vea un número grande como 43938 en lugar de una fecha de apariencia normal, como en esta captura de pantalla a continuación:

Para reformatear la celda, selecciónela, elija el menú desplegable del elemento del grupo Número y luego elija uno de los formatos de fecha.