如何使用 Excel 日期函數

須知

• DATE 函數的語法是 =DATE(year,month,day)。例如：=DATE(1986,3,18)
• 您可以從其他單元格中提取年、月和日。例如：=DATE(A2,B2,C2)
• 使用否定參數減去月份和日期。例如：=DATE(2020,-2, -15)

本文介紹如何在每個版本的 Excel 中使用 Excel DATE 函數。

DATE 函數語法和參數

Excel DATE 函數結合三個值來創建日期。當您指定年、月和日時，Excel 會生成一個序列號，然後可以將其格式化為外觀正常的日期。

在 Excel 中輸入日期的典型方法是將整個日期寫在一個單元格中，但當您處理大量信息時，這會很不方便。如果日期格式不正確，例如日期與常規文本組合或分佈在多個單元格中，DATE 函數會很有用。

這是必須為 Excel 正確處理日期函數的每個實例編寫的方式：

=DATE（年、月、日）

• 年份：輸入長度為一到四位數字的年份，或輸入對工作表中數據位置的單元格引用。年份參數是必需的。
• 月：以 1 到 12（一月到十二月）之間的正整數或負整數形式輸入一年中的月份，或者輸入對數據位置的單元格引用。月份參數是必需的。
• 日：以 1 到 31 之間的正整數或負整數形式輸入月中的某一天，或者輸入對數據位置的單元格引用。day 參數是必需的。

附加日期函數信息

以下是有關年、月和日參數的其他一些重要信息：

年

• 默認情況下，Excel 使用 1900 年日期系統，這意味著 DATE 函數不會正確顯示早於 1900 年的年份。
• 輸入0作為年份值與輸入 1900 相同，1等於 1901，105 等於2005，等等。

月

• 超過12作為月份值會將月份數添加到年份值。然後， 13將日期加上一年零一個月。
• 使用負數作為月份值將從一年中的第一個月減去該月份數，再加上一個。

天

• 如果日值超過該月的天數，超出的天數將添加到下個月的第一天。
• 負日值從一個月的第一天減去該天數，再加上一天。

日期函數示例

下面是一些使用 DATE 函數的實際公式：

其他單元格中的年、月和日


=DATE(A2,B2,C2)


此 DATE 函數示例使用 A2 表示年，B2 表示月，C2 表示日。

公式中的年份和另一個單元格中的月份和日期


=DATE(2020,A2,B2)


您還可以混合獲取數據的方式。在此示例中，我們將 2020 作為年份參數，但月份和日期是從其他單元格中提取的。

使用負月參數減去月份


=DATE(2020,-2,15)


在這裡，我們在月份空間中使用負數。從 2020 年 1 月開始（因為公式包括 2020 年），這會向後移動而不是向前移動。此 DATE 公式產生 10/15/2019。

使用負日參數減去天數


=DATE(2020,1,-5)


如果沒有負數，該日期將計算為 1/5/2020。但是，負日值是從 1/1/2020 減去五天（加一），得到日期 12/26/2019。

大型日期和月份參數


=DATE(2020,19,50)


這個例子結合了上面提到的一些規則。年份值將從 2020 開始增加，因為月份超過 12，並且將計算的月份也會發生變化，因為日期值超過了任何一個月的天數。此 DATE 公式產生 8/19/2021。

在另一個單元格中添加 10 年至今


=DATE(YEAR(A2)+10,MONTH(A2),DAY(A2))


Excel DATE 函數也可以與其他日期一起使用，例如將時間添加到現有日期。在此示例中，我們希望查看比現有日期晚 10 年的日期。現有日期位於單元格 E2 中，因此我們需要以從 E2 中提取年、月和日的方式編寫此公式，同時將年值加 10。

計算一年中的天數


=A2-DATE(YEAR(A2),1,0)


下面是 DATE 函數的一個類似示例，我們在其中計算單元格 E10 中的日期在一年中有多少天。例如，1/1/2020 是一年中的一天，1 月 5 日是五天，依此類推。在此示例中，E10 為 8/4/2018，因此結果為 216。

將日期作為文本轉換為格式正確的日期


=DATE(LEFT(A2,4),MID(A2,5,2),RIGHT(A2,2))


如果您正在處理的單元格包含完整日期，但它的格式為文本，例如 20200417，您可以使用此 DATE 公式，結合 LEFT、MID 和 RIGHT 函數，將單元格轉換為格式正確的日期。

這是在用 LEFT(A2,4) 從左邊提取前四位數字，通過 MID(A2,5,2) 在第五個字符處從中間提取兩位數字，並將它與來自右邊是 RIGHT(A2,2)。計算日期為 4/17/2020。

有關詳細信息，請參閱我們關於使用 Excel 的 LEFT、RIGHT 和 MID 函數的文章。

今年和本月的特定日期


=DATE(YEAR(TODAY()), MONTH(TODAY()), 5)


TODAY 函數可以與 DATE 函數一起使用來提取有關今天的信息。例如，要提醒自己每月 5 號支付賬單，您可以使用此 DATE 公式自動添加當前年份和月份，然後將 5（或單元格引用）作為日期值。

當月份為文本時計算日期


=DATE(A2,MONTH(1&B2),C2)


有時日期包括月份的文本版本，例如六月。由於 Excel 無法將其理解為數字，因此您必須使用 MONTH 函數將其轉換為數字。我們已將其直接嵌入 DATE 公式中的月份位置，如 MONTH(1&B2)。

修復看起來不像日期的日期

如果 DATE 函數的結果顯示一串數字而不是日期，則需要將單元格格式化為日期。

例如，您可能會看到像 43938 這樣的大數字，而不是正常的日期，如下面的屏幕截圖所示：

要重新格式化單元格，請選擇它，從數字組項目中選擇下拉菜單，然後選擇一種日期格式。