Como usar a função DATA do Excel

o que saber

• A sintaxe da função DATE é =DATE(ano,mês,dia). Por exemplo: =DATA(1986,3,18)
• Você pode extrair o ano, mês e dia de outras células. Por exemplo: =DATA(A2,B2,C2)
• Subtraia meses e dias usando argumentos negativos. Por exemplo: =DATA(2020,-2,-15)

Este artigo explica como usar a função DATA do Excel em todas as versões do Excel.

Sintaxe e Argumentos da Função DATE

A função DATA do Excel combina três valores para criar uma data. Quando você especifica o ano, o mês e o dia, o Excel produz um número de série que pode ser formatado como uma data de aparência normal.

A maneira típica de inserir uma data no Excel é escrever a data inteira em uma célula, mas isso é inconveniente quando você está lidando com muitas informações. A função DATE pode ser útil se a data não estiver formatada corretamente, como se for combinada com texto normal ou se estiver espalhada por várias células.

É assim que cada instância da função de data deve ser escrita para que o Excel a processe corretamente:

=DATA (ano, mês, dia)

• Ano: insira o ano como um número de um a quatro dígitos ou insira a referência de célula para o local dos dados na planilha. O argumento ano é obrigatório.
• Mês: Insira o mês do ano como um número inteiro positivo ou negativo de 1 a 12 (janeiro a dezembro) ou insira a referência da célula ao local dos dados. O argumento do mês é obrigatório.
• Dia: Insira o dia do mês como um número inteiro positivo ou negativo de 1 a 31 ou insira a referência de célula para o local dos dados. O argumento do dia é obrigatório.

Informações Adicionais da Função de Data

Aqui estão algumas outras coisas importantes a saber sobre os argumentos de ano, mês e dia:

ANO

• Por padrão, o Excel usa o sistema de data 1900, o que significa que a função DATE não exibirá o ano corretamente para qualquer coisa anterior a 1900.
• Inserir 0 como o valor do ano é o mesmo que inserir 1900, 1 é igual a 1901, 105 é 2005, etc.

MÊS

• Exceder 12 como o valor do mês adicionará esse número de meses ao valor do ano. 13, então, acrescenta um ano e um mês à data.
• Usar um número negativo como o valor do mês subtrairá esse número de meses, mais um, do primeiro mês do ano.

DIA

• Se o valor do dia exceder o número de dias desse mês, os dias excedentes serão adicionados ao primeiro dia do próximo mês.
• Um valor de dia negativo subtrai esse número de dias, mais um, do primeiro dia do mês.

Exemplos de função DATA

Abaixo estão algumas fórmulas do mundo real que usam a função DATA:

Ano, mês e dia em outras células


=DATE(A2,B2,C2)


Este exemplo da função DATA está usando A2 para o ano, B2 para o mês e C2 para o dia.

Ano na Fórmula e Mês e Dia em Outra Célula


=DATE(2020,A2,B2)


Você também pode misturar como os dados são obtidos. Neste exemplo, estamos fazendo de 2020 o argumento do ano, mas o mês e o dia estão sendo extraídos de outras células.

Subtrair Meses Usando o Argumento do Mês Negativo


=DATE(2020,-2,15)


Aqui, estamos usando um número negativo no espaço do mês. Isso retrocede ao longo do ano em vez de avançar, começando em janeiro de 2020 (já que a fórmula inclui 2020). Esta fórmula DATE produz 15/10/2019.

Subtrair dias usando o argumento de dia negativo


=DATE(2020,1,-5)


Sem o número negativo, essa data seria calculada como 05/01/2020. No entanto, o valor do dia negativo está subtraindo cinco dias (mais um) de 01/01/2020, que produz a data 26/12/2019.

Argumentos de dias e meses grandes


=DATE(2020,19,50)


Este exemplo combina algumas das regras mencionadas acima. O valor do ano aumentará a partir de 2020 porque o mês excede 12, e o mês que será calculado também mudará, pois o valor do dia excede o número de dias em qualquer mês. Esta fórmula DATE produz 19/08/2021.

Adicionar 10 anos até a data em outra célula


=DATE(YEAR(A2)+10,MONTH(A2),DAY(A2))


A função DATE do Excel também pode ser usada com outras datas, como adicionar tempo a uma data existente. Neste exemplo, queremos ver a data que passou 10 anos de uma data existente. A data existente está na célula E2, então precisamos escrever esta fórmula de forma a extrair o ano, mês e dia de E2, mas também adicionar 10 ao valor do ano.

Calcular o número de dias no ano


=A2-DATE(YEAR(A2),1,0)


Aqui está um exemplo semelhante da função DATE onde estamos calculando quantos dias no ano a data na célula E10 tem. Por exemplo, 01/01/2020 é um dia do ano, 5 de janeiro são cinco dias e assim por diante. Neste exemplo, E10 é 04/08/2018, então o resultado é 216.

Converter data como texto para data formatada corretamente


=DATE(LEFT(A2,4),MID(A2,5,2),RIGHT(A2,2))


Se a célula com a qual você está lidando contém a data completa, mas está formatada como texto, como 20200417, você pode usar esta fórmula DATE, combinada com as funções ESQUERDA, MEIO e DIREITA, para converter a célula em uma data formatada corretamente.

O que isso está fazendo é extrair os primeiros quatro dígitos da esquerda com ESQUERDA(A2,4), pegar dois dígitos do meio no quinto caractere via MID(A2,5,2) e combiná-los com os dois últimos dígitos de a direita com DIREITA(A2,2). A data calculada é 17/04/2020.

Consulte nossos artigos sobre como usar as funções ESQUERDA, DIREITA e MID do Excel para obter mais informações.

Este ano e mês em um dia específico


=DATE(YEAR(TODAY()), MONTH(TODAY()), 5)


A função TODAY pode ser usada com a função DATE para obter informações sobre hoje. Por exemplo, para se lembrar de pagar as contas todos os meses no dia 5, você pode usar esta fórmula DATE para adicionar automaticamente o ano e o mês atuais, mas colocar 5 (ou uma referência de célula) como o valor do dia.

Calcular data quando o mês é texto


=DATE(A2,MONTH(1&B2),C2)


Às vezes, uma data inclui a versão em texto do mês, como junho. Como o Excel não entende isso como um número, você deve convertê-lo em um com a função MÊS. Incorporamos isso diretamente na fórmula DATE, na posição do mês, como MONTH(1&B2).

Corrigindo datas que não se parecem com datas

Se o resultado da função DATA mostrar vários números em vez de uma data, você precisará formatar a célula como uma data.

Por exemplo, você pode ver um número grande como 43938 em vez de uma data de aparência normal, como nesta captura de tela abaixo:

Para reformatar a célula, selecione-a, escolha o menu suspenso no item do grupo Número e escolha um dos formatos de data.