Hoe de Excel DATE-functie te gebruiken

Wat te weten

• De syntaxis voor de functie DATE is =DATE(jaar,maand,dag). Bijvoorbeeld: =DATUM(1986,3,18)
• U kunt het jaar, de maand en de dag uit andere cellen halen. Bijvoorbeeld: =DATUM(A2,B2,C2)
• Trek maanden en dagen af ​​met behulp van negatieve argumenten. Bijvoorbeeld: =DATUM(2020,-2, -15)

In dit artikel wordt uitgelegd hoe u de Excel DATE-functie in elke versie van Excel gebruikt.

DATUM Functie Syntax & Argumenten

De Excel DATE-functie combineert drie waarden om een ​​datum te maken. Wanneer u het jaar, de maand en de dag opgeeft, produceert Excel een serienummer dat vervolgens kan worden opgemaakt als een normaal ogende datum.

De typische manier om een ​​datum in Excel in te voeren, is door de hele datum in één cel te schrijven, maar dat is onhandig als je met veel informatie te maken hebt. De DATUM-functie kan handig zijn als de datum niet correct is opgemaakt, bijvoorbeeld als deze wordt gecombineerd met gewone tekst of wordt verspreid over meerdere cellen.

Dit is hoe elk exemplaar van de datumfunctie moet worden geschreven voor Excel om het correct te verwerken:

=DATUM (jaar,maand,dag)

• Jaar: Voer het jaar in als een getal van één tot vier cijfers lang of voer de celverwijzing in naar de locatie van de gegevens in het werkblad. Het jaarargument is vereist.
• Maand: voer de maand van het jaar in als een positief of negatief geheel getal van 1 tot 12 (januari tot december) of voer de celverwijzing naar de locatie van de gegevens in. Het argument maand is vereist.
• Dag: voer de dag van de maand in als een positief of negatief geheel getal van 1 tot 31 of voer de celverwijzing naar de locatie van de gegevens in. Het argument dag is vereist.

Aanvullende datumfunctie-informatie

Hier zijn enkele andere belangrijke dingen die u moet weten over de jaar-, maand- en dagargumenten:

JAAR

• Standaard gebruikt Excel het datumsysteem 1900, wat betekent dat de functie DATUM het jaar niet correct weergeeft voor iets dat ouder is dan 1900.
• Het invoeren van 0 als jaarwaarde is hetzelfde als het invoeren van 1900, 1 is gelijk aan 1901, 105 is 2005, enz.

MAAND

• Als u 12 overschrijdt als maandwaarde, wordt dat aantal maanden opgeteld bij de jaarwaarde. 13 voegt dan een jaar en een maand toe aan de datum.
• Als u een negatief getal als maandwaarde gebruikt, wordt dat aantal maanden, plus één, afgetrokken van de eerste maand van het jaar.

DAG

• Als de dagwaarde groter is dan het aantal dagen dat die maand heeft, worden de overtollige dagen opgeteld bij de eerste dag van de volgende maand.
• Een negatieve dagwaarde trekt dat aantal dagen plus één af van de eerste dag van de maand.

DATE Functievoorbeelden

Hieronder staan ​​een aantal real-world formules die de DATE-functie gebruiken:

Jaar, maand en dag in andere cellen


=DATE(A2,B2,C2)


Dit voorbeeld van de DATE-functie gebruikt A2 voor het jaar, B2 voor de maand en C2 voor de dag.

Jaar in formule en maand en dag in een andere cel


=DATE(2020,A2,B2)


U kunt ook mixen hoe de gegevens worden verkregen. In dit voorbeeld maken we van 2020 het jaarargument, maar maand en dag worden uit andere cellen gehaald.

Maanden aftrekken met behulp van een negatief maandargument


=DATE(2020,-2,15)


Hier gebruiken we een negatief getal in de maandruimte. Dit gaat achteruit door het jaar in plaats van vooruit, beginnend op januari 2020 (aangezien de formule 2020 omvat). Deze DATE-formule levert 15-10-2019 op.

Trek dagen af ​​met behulp van een negatief dagargument


=DATE(2020,1,-5)


Zonder het negatieve getal zou deze datum worden berekend als 5-1-2020. De negatieve dagwaarde trekt echter vijf dagen (plus één) af van 1-1-2020, wat de datum 26-12-2019 oplevert.

Grote dag- en maandargumenten


=DATE(2020,19,50)


Dit voorbeeld combineert enkele van de hierboven genoemde regels. De jaarwaarde zal toenemen vanaf 2020 omdat maand groter is dan 12, en de maand die wordt berekend zal ook veranderen omdat de dagwaarde het aantal dagen in een willekeurige maand overschrijdt. Deze DATE-formule levert 8/19/2021 op.

Voeg 10 jaar toe aan datum in een andere cel


=DATE(YEAR(A2)+10,MONTH(A2),DAY(A2))


De Excel DATUM-functie kan ook worden gebruikt met andere datums, bijvoorbeeld om tijd toe te voegen aan een bestaande datum. In dit voorbeeld willen we de datum zien die 10 jaar na een bestaande datum ligt. De bestaande datum staat in cel E2, dus we moeten deze formule zo schrijven dat het jaar, de maand en de dag uit E2 worden gehaald, maar er wordt ook 10 aan de jaarwaarde toegevoegd.

Bereken het aantal dagen in het jaar


=A2-DATE(YEAR(A2),1,0)


Hier is een soortgelijk voorbeeld van de functie DATUM, waarbij we berekenen hoeveel dagen in het jaar de datum in cel E10 is. Bijvoorbeeld, 1/1/2020 is één dag in het jaar, 5 januari is vijf dagen, enzovoort. In dit voorbeeld is E10 4-8-2018, dus het resultaat is 216.

Converteer datum als tekst naar correct opgemaakte datum


=DATE(LEFT(A2,4),MID(A2,5,2),RIGHT(A2,2))


Als de cel waarmee je te maken hebt de volledige datum bevat, maar is opgemaakt als tekst, zoals 20200417, kun je deze DATUM-formule gebruiken, gecombineerd met de functies LINKS, MIDDEN en RECHTS, om de cel te converteren naar een correct opgemaakte datum.

Wat dit doet is de eerste vier cijfers van links extraheren met LINKS(A2,4), twee cijfers uit het midden nemen bij het vijfde teken via MID(A2,5,2), en deze combineren met de laatste twee cijfers van rechts met RECHTS(A2,2). De berekende datum is 17-04-2020.

Zie onze artikelen over het gebruik van de functies LINKS, RECHTS en MID van Excel voor meer informatie.

Dit jaar en deze maand op een specifieke dag


=DATE(YEAR(TODAY()), MONTH(TODAY()), 5)


De TODAY-functie kan worden gebruikt met de DATE-functie om informatie over vandaag op te halen. Om jezelf er bijvoorbeeld aan te herinneren om elke maand op de 5e rekeningen te betalen, kun je deze DATE-formule gebruiken om automatisch het huidige jaar en de huidige maand toe te voegen, maar plaats dan 5 (of een celverwijzing) als de dagwaarde.

Bereken datum wanneer maand tekst is


=DATE(A2,MONTH(1&B2),C2)


Soms bevat een datum de tekstversie van de maand, zoals juni. Omdat Excel dit niet als een getal begrijpt, moet u het naar één converteren met de functie MAAND. We hebben dit direct in de DATE-formule ingebed, in de maandpositie, als MONTH(1&B2).

Datums vastleggen die niet op datums lijken

Als het resultaat van de functie DATUM een aantal getallen weergeeft in plaats van een datum, moet u de cel opmaken als een datum.

U ziet bijvoorbeeld een groot getal zoals 43938 in plaats van een normaal ogende datum, zoals in deze schermafbeelding hieronder:

Om de cel opnieuw op te maken, selecteert u deze, kiest u het vervolgkeuzemenu uit het groepsitem Getal en kiest u vervolgens een van de datumnotaties.