Excel DATE 함수를 사용하는 방법

2022/12/07

알아야 할 사항

DATE 함수의 구문은 =DATE(년,월,일)입니다. 예: =DATE(1986,3,18)
다른 셀에서 연도, 월, 일을 가져올 수 있습니다. 예: =DATE(A2,B2,C2)
음의 인수를 사용하여 월과 일을 뺍니다. 예: =DATE(2020,-2, -15)

이 문서에서는 모든 버전의 Excel에서 Excel DATE 함수를 사용하는 방법에 대해 설명합니다.

DATE 함수 구문 및 인수

Excel DATE 함수는 세 개의 값을 결합하여 날짜를 만듭니다. 연도, 월, 일을 지정하면 Excel에서 정상적인 날짜로 서식을 지정할 수 있는 일련 번호를 생성합니다.

엑셀에서 날짜를 입력하는 일반적인 방법은 하나의 셀에 전체 날짜를 입력하는 것이지만 많은 정보를 다룰 때 불편하다. DATE 함수는 날짜가 일반 텍스트와 결합되거나 여러 셀에 걸쳐 있는 경우와 같이 날짜 형식이 올바르지 않은 경우에 유용할 수 있습니다.

날짜 함수의 모든 인스턴스를 Excel에서 올바르게 처리하기 위해 작성해야 하는 방법은 다음과 같습니다.

=날짜 (년,월,일)

연도: 연도를 1~4자리 숫자로 입력하거나 워크시트의 데이터 위치에 대한 셀 참조를 입력합니다. 연도 인수가 필요합니다.
월: 1~12(1월~12월) 사이의 양수 또는 음수로 월을 입력하거나 데이터 위치에 대한 셀 참조를 입력합니다. 월 인수가 필요합니다.
일: 1에서 31 사이의 양수 또는 음수로 날짜를 입력하거나 데이터 위치에 대한 셀 참조를 입력합니다. 일 인수가 필요합니다.

추가 날짜 기능 정보

다음은 연도, 월, 일 인수에 대해 알아야 할 몇 가지 중요한 사항입니다.

년도

기본적으로 Excel은 1900 날짜 체계를 사용합니다. 즉, DATE 함수는 1900년보다 오래된 항목에 대해 연도를 올바르게 표시하지 않습니다.
연도 값으로 0 을 입력 하면 1900을 입력하는 것과 같고, 1 은 1901, 105 는 2005 를 입력하는 것과 같습니다.

월

월 값이 12 를 초과하면 해당 월 수가 연도 값에 추가됩니다. 그러면 13 은 날짜에 1년 1개월을 추가합니다.
음수를 월 값으로 사용하면 해당 월 수에 1을 더한 값을 연도의 첫 번째 달에서 뺍니다.

낮

일 값이 해당 월의 일 수를 초과하면 초과 일수가 다음 달의 1일에 추가됩니다.
음수 일 값은 월의 첫 번째 날에서 해당 일 수에 1을 더한 값을 뺍니다.

DATE 함수 예

다음은 DATE 함수를 사용하는 여러 실제 수식입니다.

다른 셀의 연도, 월, 일

=DATE(A2,B2,C2)

DATE 함수의 이 예에서는 연도에 A2, 월에 B2, 일에 C2를 사용합니다.

수식의 연도 및 다른 셀의 월 및 일

=DATE(2020,A2,B2)

데이터를 얻는 방법을 혼합할 수도 있습니다. 이 예에서는 2020을 연도 인수로 만들고 있지만 다른 셀에서 월과 일을 가져오고 있습니다.

음수 월 인수를 사용하여 월 빼기

=DATE(2020,-2,15)

여기에서는 월 공간에 음수를 사용하고 있습니다. 이것은 2020년 1월부터 시작하여 앞으로가 아니라 뒤로 이동합니다(공식에 2020이 포함되어 있기 때문). 이 DATE 수식은 2019년 10월 15일을 생성합니다.

음의 날짜 인수를 사용하여 날짜 빼기

=DATE(2020,1,-5)

음수가 없으면 이 날짜는 2020년 1월 5일로 계산됩니다. 그러나 음수 일 값은 2020년 1월 1일에서 5일(더하기 1)을 빼서 2019년 12월 26일 날짜를 생성합니다.

큰 일 및 월 인수

=DATE(2020,19,50)

이 예는 위에서 언급한 몇 가지 규칙을 결합한 것입니다. 2020년부터는 월이 12를 초과하므로 연도 값이 증가하고, 일 값이 어느 달이든 일수를 초과하므로 계산되는 월도 변경됩니다. 이 DATE 수식은 2021년 8월 19일을 생성합니다.

다른 셀에서 날짜에 10년 더하기

=DATE(YEAR(A2)+10,MONTH(A2),DAY(A2))

Excel DATE 함수는 기존 날짜에 시간을 추가하는 것과 같이 다른 날짜와 함께 사용할 수도 있습니다. 이 예에서는 기존 날짜보다 10년 지난 날짜를 확인하려고 합니다. 기존 날짜는 셀 E2에 있으므로 E2에서 연도, 월, 일을 추출하고 연도 값에 10을 더하는 방식으로 이 수식을 작성해야 합니다.

연도의 일수 계산

=A2-DATE(YEAR(A2),1,0)

다음은 셀 E10의 날짜가 해당 연도의 몇 일인지 계산하는 DATE 함수의 유사한 예입니다. 예를 들어 2020년 1월 1일은 1년의 하루이고 1월 5일은 5일입니다. 이 예에서 E10은 2018년 8월 4일이므로 결과는 216입니다.

텍스트 형식의 날짜를 적절한 형식의 날짜로 변환

=DATE(LEFT(A2,4),MID(A2,5,2),RIGHT(A2,2))

처리하려는 셀에 전체 날짜가 포함되어 있지만 20200417과 같은 텍스트 형식인 경우 이 DATE 수식을 LEFT, MID 및 RIGHT 함수와 결합하여 셀을 올바른 형식의 날짜로 변환할 수 있습니다.

이것이 하는 일은 LEFT(A2,4)로 왼쪽에서 처음 네 자리를 추출하고, MID(A2,5,2)를 통해 다섯 번째 문자에서 중간에서 두 자리를 가져와서 마지막 두 자리와 결합하는 것입니다. 오른쪽을 RIGHT(A2,2)로. 계산된 날짜는 2020-04-17입니다.

자세한 내용은 Excel의 LEFT, RIGHT 및 MID 기능 사용에 대한 기사를 참조하십시오.

올해와 달의 특정 날짜

=DATE(YEAR(TODAY()), MONTH(TODAY()), 5)

TODAY 함수는 DATE 함수와 함께 사용하여 오늘에 대한 정보를 가져올 수 있습니다. 예를 들어 매월 5일에 청구서를 지불해야 한다는 것을 상기시키려면 이 DATE 수식을 사용하여 현재 연도와 월을 자동으로 추가한 다음 일 값으로 5(또는 셀 참조)를 배치할 수 있습니다.

월이 텍스트인 경우 날짜 계산

=DATE(A2,MONTH(1&B2),C2)

경우에 따라 날짜에는 6월과 같이 해당 월의 텍스트 버전이 포함됩니다. Excel에서는 이것을 숫자로 인식하지 못하므로 MONTH 함수를 사용하여 1로 변환해야 합니다. 이를 DATE 수식의 월 위치에 MONTH(1&B2)로 직접 포함했습니다.

날짜처럼 보이지 않는 고정 날짜

DATE 함수의 결과에 날짜 대신 여러 개의 숫자가 표시되면 셀 서식을 날짜로 지정해야 합니다.

예를 들어 아래 스크린샷과 같이 일반적인 날짜 대신 43938과 같은 큰 숫자가 표시될 수 있습니다.

셀 서식 을 다시 지정하려면 셀을 선택하고 숫자 그룹 항목에서 드롭다운 메뉴를 선택한 다음 날짜 서식 중 하나를 선택합니다.