Come utilizzare la funzione DATA di Excel

Cosa sapere

• La sintassi per la funzione DATA è =DATA(anno,mese,giorno). Ad esempio: =DATA(1986,3,18)
• Puoi estrarre l’anno, il mese e il giorno da altre celle. Ad esempio: =DATA(A2,B2,C2)
• Sottrai mesi e giorni usando argomenti negativi. Ad esempio: =DATA(2020,-2, -15)

Questo articolo spiega come utilizzare la funzione DATA di Excel in ogni versione di Excel.

DATA Funzione Sintassi e argomenti

La funzione DATA di Excel combina tre valori per creare una data. Quando si specifica l’anno, il mese e il giorno, Excel produce un numero di serie che può quindi essere formattato come una data dall’aspetto normale.

Il modo tipico per inserire una data in Excel è scrivere l’intera data all’interno di una cella, ma è scomodo quando hai a che fare con molte informazioni. La funzione DATA può essere utile se la data non è formattata correttamente, ad esempio se è combinata con testo normale o se è distribuita su più celle.

Ecco come ogni istanza della funzione data deve essere scritta affinché Excel la elabori correttamente:

=DATA (anno,mese,giorno)

• Anno: inserisci l’anno come numero da una a quattro cifre o inserisci il riferimento di cella alla posizione dei dati nel foglio di lavoro. L’argomento dell’anno è obbligatorio.
• Mese: inserisci il mese dell’anno come numero intero positivo o negativo compreso tra 1 e 12 (da gennaio a dicembre) oppure inserisci il riferimento di cella alla posizione dei dati. L’argomento del mese è obbligatorio.
• Giorno: inserisci il giorno del mese come numero intero positivo o negativo compreso tra 1 e 31 oppure inserisci il riferimento di cella alla posizione dei dati. L’argomento giorno è obbligatorio.

Ulteriori informazioni sulla funzione data

Ecco alcune altre cose importanti da sapere sugli argomenti di anno, mese e giorno:

ANNO

• Per impostazione predefinita, Excel utilizza il sistema di data 1900, il che significa che la funzione DATA non visualizzerà correttamente l’anno per qualsiasi elemento precedente al 1900.
• Inserire 0 come valore dell’anno equivale a inserire 1900, 1 è uguale a 1901, 105 è 2005, ecc.

MESE

• Il superamento di 12 come valore del mese aggiungerà quel numero di mesi al valore dell’anno. 13, poi, aggiunge un anno e un mese alla data.
• L’utilizzo di un numero negativo come valore del mese sottrarrà tale numero di mesi, più uno, dal primo mese dell’anno.

GIORNO

• Se il valore del giorno supera il numero di giorni del mese, i giorni in eccesso vengono aggiunti al primo giorno del mese successivo.
• Un valore di giorno negativo sottrae quel numero di giorni, più uno, dal primo giorno del mese.

Esempi di funzione DATA

Di seguito sono riportate alcune formule del mondo reale che utilizzano la funzione DATA:

Anno, mese e giorno in altre celle


=DATE(A2,B2,C2)


Questo esempio della funzione DATA utilizza A2 per l’anno, B2 per il mese e C2 per il giorno.

Anno in formula e mese e giorno in un’altra cella


=DATE(2020,A2,B2)


Puoi anche combinare il modo in cui vengono ottenuti i dati. In questo esempio, stiamo impostando 2020 come argomento dell’anno, ma il mese e il giorno vengono estratti da altre celle.

Sottrai i mesi utilizzando l’argomento del mese negativo


=DATE(2020,-2,15)


Qui stiamo usando un numero negativo nello spazio del mese. Questo si sposta indietro nel corso dell’anno invece che in avanti, a partire da gennaio 2020 (poiché la formula include il 2020). Questa formula DATE produce 15/10/2019.

Sottrai i giorni usando l’argomento del giorno negativo


=DATE(2020,1,-5)


Senza il numero negativo, questa data verrebbe calcolata come 05/01/2020. Tuttavia, il valore del giorno negativo sottrae cinque giorni (più uno) da 1/1/2020, che produce la data 26/12/2019.

Grandi argomenti relativi a giorno e mese


=DATE(2020,19,50)


Questo esempio combina alcune delle regole menzionate sopra. Il valore dell’anno aumenterà dal 2020 perché il mese supera 12 e anche il mese che verrà calcolato cambierà poiché il valore del giorno supera il numero di giorni in qualsiasi mese. Questa formula DATE produce 8/19/2021.

Aggiungi 10 anni fino ad oggi in un’altra cella


=DATE(YEAR(A2)+10,MONTH(A2),DAY(A2))


La funzione DATA di Excel può essere utilizzata anche con altre date, ad esempio per aggiungere l’ora a una data esistente. In questo esempio, vogliamo vedere la data che è 10 anni dopo una data esistente. La data esistente si trova nella cella E2, quindi dobbiamo scrivere questa formula in modo da estrarre l’anno, il mese e il giorno da E2 ma aggiungere anche 10 al valore dell’anno.

Calcola il numero di giorni nell’anno


=A2-DATE(YEAR(A2),1,0)


Ecco un esempio simile della funzione DATE in cui calcoliamo quanti giorni nell’anno è la data nella cella E10. Ad esempio, 1/1/2020 è un giorno dell’anno, il 5 gennaio è di cinque giorni e così via. In questo esempio, E10 è 8/4/2018, quindi il risultato è 216.

Converti la data come testo in una data correttamente formattata


=DATE(LEFT(A2,4),MID(A2,5,2),RIGHT(A2,2))


Se la cella con cui hai a che fare contiene la data completa ma è formattata come testo, ad esempio 20200417, puoi utilizzare questa formula DATA, combinata con le funzioni LEFT, MID e RIGHT, per convertire la cella in una data correttamente formattata.

Quello che sta facendo è estrarre le prime quattro cifre da sinistra con LEFT(A2,4), prendere due cifre dal centro al quinto carattere tramite MID(A2,5,2) e combinarle con le ultime due cifre da a destra con DESTRA(A2,2). La data calcolata è 17/04/2020.

Consulta i nostri articoli sull’utilizzo delle funzioni SINISTRA, DESTRA e MID di Excel per ulteriori informazioni.

Quest’anno e mese in un giorno specifico


=DATE(YEAR(TODAY()), MONTH(TODAY()), 5)


La funzione OGGI può essere utilizzata con la funzione DATA per estrarre informazioni su oggi. Ad esempio, per ricordarti di pagare le bollette ogni mese il 5, puoi utilizzare questa formula DATE per aggiungere automaticamente l’anno e il mese correnti, ma poi posizionare 5 (o un riferimento di cella) come valore del giorno.

Calcola la data quando il mese è testo


=DATE(A2,MONTH(1&B2),C2)


A volte una data include la versione testuale del mese, come giugno. Poiché Excel non lo interpreta come un numero, devi convertirlo in uno con la funzione MESE. L’abbiamo incorporato direttamente nella formula DATE, nella posizione del mese, come MONTH(1&B2).

Fissare le date che non sembrano date

Se il risultato della funzione DATA mostra una serie di numeri anziché una data, dovrai formattare la cella come una data.

Ad esempio, potresti vedere un numero elevato come 43938 invece di una data dall’aspetto normale, come in questo screenshot qui sotto:

Per riformattare la cella, selezionala, scegli il menu a discesa dalla voce Gruppo numeri, quindi scegli uno dei formati di data.