Comment utiliser la fonction Excel DATE

Ce qu’il faut savoir

• La syntaxe de la fonction DATE est =DATE(année,mois,jour). Par exemple: =DATE(1986,3,18)
• Vous pouvez extraire l’année, le mois et le jour d’autres cellules. Par exemple: =DATE(A2,B2,C2)
• Soustraire des mois et des jours en utilisant des arguments négatifs. Par exemple: =DATE(2020,-2, -15)

Cet article explique comment utiliser la fonction Excel DATE dans chaque version d’Excel.

Syntaxe et arguments de la fonction DATE

La fonction Excel DATE combine trois valeurs pour créer une date. Lorsque vous spécifiez l’année, le mois et le jour, Excel produit un numéro de série qui peut ensuite être formaté comme une date d’apparence normale.

La façon typique d’entrer une date dans Excel est d’écrire la date entière dans une cellule, mais ce n’est pas pratique lorsque vous traitez beaucoup d’informations. La fonction DATE peut être utile si la date n’est pas formatée correctement, comme si elle est combinée avec du texte normal ou est répartie sur plusieurs cellules.

Voici comment chaque instance de la fonction date doit être écrite pour qu’Excel la traite correctement:

=DATE (année,mois,jour)

• Année: saisissez l’année sous la forme d’un nombre de un à quatre chiffres ou saisissez la référence de cellule à l’emplacement des données dans la feuille de calcul. L’argument année est obligatoire.
• Mois: Entrez le mois de l’année sous la forme d’un entier positif ou négatif de 1 à 12 (janvier à décembre) ou entrez la référence de cellule à l’emplacement des données. L’argument du mois est obligatoire.
• Jour: Entrez le jour du mois sous la forme d’un entier positif ou négatif de 1 à 31 ou entrez la référence de cellule à l’emplacement des données. L’argument jour est obligatoire.

Informations supplémentaires sur la fonction de date

Voici quelques autres choses importantes à savoir sur les arguments année, mois et jour:

AN

• Par défaut, Excel utilise le système de date 1900, ce qui signifie que la fonction DATE n’affichera pas l’année correctement pour tout ce qui est antérieur à 1900.
• Entrer 0 comme valeur de l’année revient à entrer 1900, 1 est égal à 1901, 105 est 2005, etc.

MOIS

• Si vous dépassez 12 comme valeur de mois, ce nombre de mois sera ajouté à la valeur de l’année. 13 ajoute alors un an et un mois à la date.
• L’utilisation d’un nombre négatif comme valeur de mois soustraira ce nombre de mois, plus un, du premier mois de l’année.

JOURNÉE

• Si la valeur du jour dépasse le nombre de jours de ce mois, les jours excédentaires sont ajoutés au premier jour du mois suivant.
• Une valeur de jour négative soustrait ce nombre de jours, plus un, du premier jour du mois.

Exemples de fonction DATE

Vous trouverez ci-dessous un certain nombre de formules du monde réel qui utilisent la fonction DATE:

Année, mois et jour dans d’autres cellules


=DATE(A2,B2,C2)


Cet exemple de la fonction DATE utilise A2 pour l’année, B2 pour le mois et C2 pour le jour.

Année dans la formule et mois et jour dans une autre cellule


=DATE(2020,A2,B2)


Vous pouvez également mélanger la façon dont les données sont obtenues. Dans cet exemple, nous faisons de 2020 l’argument de l’année, mais le mois et le jour sont extraits d’autres cellules.

Soustraire des mois à l’aide d’un argument de mois négatif


=DATE(2020,-2,15)


Ici, nous utilisons un nombre négatif dans l’espace des mois. Cela recule dans l’année au lieu d’avancer, à partir de janvier 2020 (puisque la formule inclut 2020). Cette formule DATE produit 15/10/2019.

Soustraire des jours à l’aide d’un argument de jour négatif


=DATE(2020,1,-5)


Sans le nombre négatif, cette date serait calculée comme 05/01/2020. Cependant, la valeur de jour négative soustrait cinq jours (plus un) à partir du 01/01/2020, ce qui produit la date 26/12/2019.

Grands arguments de jour et de mois


=DATE(2020,19,50)


Cet exemple combine quelques-unes des règles mentionnées ci-dessus. La valeur de l’année augmentera à partir de 2020 car le mois dépasse 12, et le mois qui sera calculé changera également puisque la valeur du jour dépasse le nombre de jours de n’importe quel mois. Cette formule DATE produit 19/08/2021.

Ajouter 10 ans à ce jour dans une autre cellule


=DATE(YEAR(A2)+10,MONTH(A2),DAY(A2))


La fonction Excel DATE peut également être utilisée avec d’autres dates, comme pour ajouter du temps à une date existante. Dans cet exemple, nous voulons voir la date qui est 10 ans après une date existante. La date existante est dans la cellule E2, nous devons donc écrire cette formule de manière à extraire l’année, le mois et le jour de E2, mais ajoute également 10 à la valeur de l’année.

Calculer le nombre de jours dans l’année


=A2-DATE(YEAR(A2),1,0)


Voici un exemple similaire de la fonction DATE où nous calculons le nombre de jours dans l’année de la date dans la cellule E10. Par exemple, le 01/01/2020 correspond à un jour dans l’année, le 5 janvier à cinq jours, etc. Dans cet exemple, E10 correspond au 04/08/2018, le résultat est donc 216.

Convertir la date sous forme de texte en date correctement formatée


=DATE(LEFT(A2,4),MID(A2,5,2),RIGHT(A2,2))


Si la cellule que vous traitez contient la date complète mais qu’elle est formatée en tant que texte, comme 20200417, vous pouvez utiliser cette formule DATE, combinée avec les fonctions LEFT, MID et RIGHT, pour convertir la cellule en une date correctement formatée.

Ce que cela fait, c’est extraire les quatre premiers chiffres de gauche avec GAUCHE(A2,4), prendre deux chiffres du milieu au cinquième caractère via MID(A2,5,2), et le combiner avec les deux derniers chiffres de la droite avec DROITE(A2,2). La date calculée est le 17/04/2020.

Consultez nos articles sur l’utilisation des fonctions GAUCHE, DROITE et MILIEU d’Excel pour plus d’informations.

Cette année et ce mois un jour spécifique


=DATE(YEAR(TODAY()), MONTH(TODAY()), 5)


La fonction AUJOURD’HUI peut être utilisée avec la fonction DATE pour extraire des informations sur aujourd’hui. Par exemple, pour vous rappeler de payer vos factures tous les mois le 5, vous pouvez utiliser cette formule DATE pour ajouter automatiquement l’année et le mois en cours, mais placez ensuite 5 (ou une référence de cellule) comme valeur de jour.

Calculer la date lorsque le mois est du texte


=DATE(A2,MONTH(1&B2),C2)


Parfois, une date inclut la version texte du mois, comme juin. Comme Excel ne comprend pas cela comme un nombre, vous devez le convertir en un avec la fonction MOIS. Nous l’avons intégré directement dans la formule DATE, à la position du mois, sous la forme MONTH(1&B2).

Fixer des dates qui ne ressemblent pas à des dates

Si le résultat de la fonction DATE affiche un groupe de nombres au lieu d’une date, vous devrez formater la cellule en tant que date.

Par exemple, vous pourriez voir un grand nombre comme 43938 au lieu d’une date normale, comme dans cette capture d’écran ci-dessous:

Pour reformater la cellule, sélectionnez-la, choisissez le menu déroulant dans l’élément de groupe Nombre, puis choisissez l’un des formats de date.