So verwenden Sie die Excel-DATUM-Funktion

Was Sie wissen sollten

• Die Syntax für die DATE-Funktion lautet =DATE(year,month,day). Zum Beispiel: =DATUM(1986,3,18)
• Sie können das Jahr, den Monat und den Tag aus anderen Zellen ziehen. Zum Beispiel: =DATUM(A2,B2,C2)
• Subtrahieren Sie Monate und Tage mit negativen Argumenten. Zum Beispiel: =DATUM(2020,-2, -15)

In diesem Artikel wird erläutert, wie Sie die Excel-DATUM-Funktion in jeder Version von Excel verwenden.

Syntax und Argumente der DATE-Funktion

Die Excel-Funktion DATE kombiniert drei Werte, um ein Datum zu erstellen. Wenn Sie das Jahr, den Monat und den Tag angeben, erzeugt Excel eine Seriennummer, die dann als normal aussehendes Datum formatiert werden kann.

Die typische Art, ein Datum in Excel einzugeben, besteht darin, das gesamte Datum in eine Zelle zu schreiben, aber das ist unpraktisch, wenn Sie mit vielen Informationen arbeiten. Die DATE-Funktion kann nützlich sein, wenn das Datum nicht korrekt formatiert ist, z. B. wenn es mit normalem Text kombiniert oder über mehrere Zellen verteilt ist.

So muss jede Instanz der Datumsfunktion geschrieben werden, damit Excel sie korrekt verarbeitet:

= DATUM (Jahr, Monat, Tag)

• Jahr: Geben Sie das Jahr als ein- bis vierstellige Zahl ein oder geben Sie den Zellbezug zum Speicherort der Daten im Arbeitsblatt ein. Das Jahresargument ist erforderlich.
• Monat: Geben Sie den Monat des Jahres als positive oder negative Ganzzahl von 1 bis 12 (Januar bis Dezember) ein oder geben Sie den Zellbezug zum Speicherort der Daten ein. Das Monatsargument ist erforderlich.
• Tag: Geben Sie den Tag des Monats als positive oder negative Ganzzahl von 1 bis 31 ein oder geben Sie den Zellbezug zum Speicherort der Daten ein. Das Tagesargument ist erforderlich.

Zusätzliche Informationen zur Datumsfunktion

Hier sind einige andere wichtige Dinge, die Sie über die Jahres-, Monats- und Tagesargumente wissen sollten:

JAHR

• Standardmäßig verwendet Excel das 1900-Datumssystem, was bedeutet, dass die DATE-Funktion das Jahr für alles, was älter als 1900 ist, nicht korrekt anzeigt.
• Die Eingabe von 0 als Jahreswert entspricht der Eingabe von 1900, 1 entspricht 1901, 105 entspricht 2005 usw.

MONAT

• Wenn Sie 12 als Monatswert überschreiten, wird diese Anzahl von Monaten zum Jahreswert hinzugefügt. 13 fügt dann dem Datum ein Jahr und einen Monat hinzu.
• Wenn Sie eine negative Zahl als Monatswert verwenden, wird diese Anzahl von Monaten plus eins vom ersten Monat des Jahres abgezogen.

TAG

• Wenn der Tageswert die Anzahl der Tage dieses Monats überschreitet, werden die überschüssigen Tage zum ersten Tag des nächsten Monats hinzugefügt.
• Ein negativer Tageswert subtrahiert diese Anzahl von Tagen plus eins vom ersten Tag des Monats.

Beispiele für DATE-Funktionen

Im Folgenden finden Sie eine Reihe von Formeln aus der Praxis, die die DATE-Funktion verwenden:

Jahr, Monat und Tag in anderen Zellen


=DATE(A2,B2,C2)


Dieses Beispiel der DATE-Funktion verwendet A2 für das Jahr, B2 für den Monat und C2 für den Tag.

Jahr in Formel und Monat & Tag in einer anderen Zelle


=DATE(2020,A2,B2)


Sie können auch mischen, wie die Daten erhalten werden. In diesem Beispiel machen wir 2020 zum Jahresargument, aber Monat und Tag werden aus anderen Zellen gezogen.

Subtrahieren Sie Monate mit dem negativen Monatsargument


=DATE(2020,-2,15)


Hier verwenden wir eine negative Zahl im Monatsbereich. Diese bewegt sich ab Januar 2020 rückwärts statt vorwärts durch das Jahr (da die Formel 2020 enthält). Diese DATE-Formel erzeugt den 15.10.2019.

Subtrahieren Sie Tage mit dem negativen Tagargument


=DATE(2020,1,-5)


Ohne die negative Zahl würde dieses Datum als 1.5.2020 berechnet werden. Der negative Tageswert subtrahiert jedoch fünf Tage (plus einen) vom 1.1.2020, was das Datum 26.12.2019 ergibt.

Große Tag- und Monatsargumente


=DATE(2020,19,50)


Dieses Beispiel kombiniert einige der oben genannten Regeln. Der Jahreswert erhöht sich ab 2020, da der Monat 12 überschreitet, und der zu berechnende Monat ändert sich ebenfalls, da der Tageswert die Anzahl der Tage in jedem Monat überschreitet. Diese DATE-Formel ergibt den 19.08.2021.

Fügen Sie 10 Jahre bis heute in einer anderen Zelle hinzu


=DATE(YEAR(A2)+10,MONTH(A2),DAY(A2))


Die Excel DATE-Funktion kann auch mit anderen Daten verwendet werden, z. B. um Zeit zu einem vorhandenen Datum hinzuzufügen. In diesem Beispiel möchten wir das Datum sehen, das 10 Jahre nach einem bestehenden Datum liegt. Das vorhandene Datum befindet sich in Zelle E2, also müssen wir diese Formel so schreiben, dass Jahr, Monat und Tag aus E2 extrahiert werden, aber auch 10 zum Jahreswert hinzugefügt wird.

Berechnen Sie die Anzahl der Tage im Jahr


=A2-DATE(YEAR(A2),1,0)


Hier ist ein ähnliches Beispiel für die DATE-Funktion, bei der wir berechnen, wie viele Tage im Jahr das Datum in Zelle E10 liegt. Zum Beispiel ist der 1.1.2020 ein Tag im Jahr, der 5. Januar fünf Tage und so weiter. In diesem Beispiel ist E10 der 4.8.2018, das Ergebnis ist also 216.

Konvertieren Sie das Datum als Text in ein korrekt formatiertes Datum


=DATE(LEFT(A2,4),MID(A2,5,2),RIGHT(A2,2))


Wenn die Zelle, mit der Sie es zu tun haben, das vollständige Datum enthält, aber als Text formatiert ist, z. B. 20200417, können Sie diese DATE-Formel in Kombination mit den Funktionen LEFT, MID und RIGHT verwenden, um die Zelle in ein ordnungsgemäß formatiertes Datum umzuwandeln.

Was dies tut, ist, die ersten vier Ziffern von links mit LEFT(A2,4) zu extrahieren, zwei Ziffern aus der Mitte beim fünften Zeichen über MID(A2,5,2) zu nehmen und sie mit den letzten beiden Ziffern von zu kombinieren rechts mit RECHTS(A2,2). Das errechnete Datum ist der 17.04.2020.

Weitere Informationen finden Sie in unseren Artikeln zur Verwendung der LEFT-, RIGHT- und MID-Funktionen von Excel.

Dieses Jahr und Monat an einem bestimmten Tag


=DATE(YEAR(TODAY()), MONTH(TODAY()), 5)


Die TODAY-Funktion kann mit der DATE-Funktion verwendet werden, um Informationen über den heutigen Tag abzurufen. Um sich beispielsweise jeden Monat am 5. daran zu erinnern, Rechnungen zu bezahlen, können Sie diese DATE-Formel verwenden, um automatisch das aktuelle Jahr und den aktuellen Monat hinzuzufügen, aber dann 5 (oder einen Zellbezug) als Tageswert zu verwenden.

Datum berechnen, wenn Monat Text ist


=DATE(A2,MONTH(1&B2),C2)


Manchmal enthält ein Datum die Textversion des Monats, z. B. Juni. Da Excel diese nicht als Zahl versteht, müssen Sie diese mit der MONTH-Funktion in eine umwandeln. Wir haben dies direkt in die DATE-Formel in der Monatsposition als MONTH(1&B2) eingebettet.

Festlegen von Daten, die nicht wie Daten aussehen

Wenn das Ergebnis der DATE-Funktion statt eines Datums eine Reihe von Zahlen anzeigt, müssen Sie die Zelle als Datum formatieren.

Beispielsweise sehen Sie möglicherweise eine große Zahl wie 43938 anstelle eines normal aussehenden Datums, wie in diesem Screenshot unten:

Um die Zelle neu zu formatieren, wählen Sie sie aus, wählen Sie das Dropdown-Menü aus dem Element der Zahlengruppe und wählen Sie dann eines der Datumsformate aus.